GEE传奇版本添加任务使者NPC教程，传奇sf一条龙领取任务的方法说明

admin

[@Main]
#IF
#ACT
Mov S$提交按钮 <确　　定>
CloseBigDialogBox
#SAY　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　\
　<背景/FCOLOR=70>:玛法170年大量<魔界大军/FCOLOR=22>侵犯我玛法大陆,我们与之对抗了整整6年\
　　我方已损失数万将士,目前已经<大量魔族/FCOLOR=22>潜伏在玛法大陆各个角落\
　 　玛法176年09月03日国王派我来民间,<筹集战备物资/FCOLOR=250>,支援前线我军\
　<--------------------------------------------------------------/FCOLOR=91>\
　<说明/FCOLOR=70>:<1./FCOLOR=146>领取任务后系统将会让你<随机/FCOLOR=250>找<一件装备!/FCOLOR=250>\
　 　　<2./FCOLOR=146>找到系统需要的装备后来提交任务即可获得<荣誉值/FCOLOR=250>!\
　 　　<3./FCOLOR=146><荣誉值/FCOLOR=250>可以用来<强化装备/FCOLOR=250>和<晋升佣兵/FCOLOR=250>等等!\
　<--------------------------------------------------------------/FCOLOR=91>\
　　　<领取任务|58#领取任务需要100元宝/@领取任务>　    　   <提交任务/@提交任务1>  　     　      <关闭对话/@exit>\


[@领取任务]
#IF
#ACT
MESSAGEBOX  成功领取任务后,系统将随机让你寻找祖玛或赤月或黄金系列的装备!\　\根据要求随便找来一件该装备提交任务即可完!\　\领取任务需要100元宝,是否需要领取? @确定 @取消


[@确定]
#IF
Equal U40 0
#ACT
GOTO @任务赋值1
#ELSEACT
GOTO @提交任务1


[@任务赋值1]
#IF
Equal U40 0
checkgamegold > 99
#ACT
gamegold - 100
Mov   U40 1
GetRandomText ..\QuestDiary\功能脚本\任务系统\任务几率控制.txt T41
GOTO @任务赋值2
#ELSEACT
MESSAGEBOX 您没有100元宝！！


[@任务赋值2]
#IF
Equal T41 祖玛
#ACT
Mov   U41 5
GOTO @提交任务1
Break



#IF
Equal T41 赤月
#ACT
Mov   U41 10
GOTO @提交任务1
Break



#IF
Equal T41 黄金
#ACT
Mov   U41 50
GOTO @提交任务1
Break


[@提交任务1]
#IF
Equal U40 1
#ACT
CloseBigDialogBox
#SAY　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　\
　<国库任务/FCOLOR=254> <Hot~> <荣誉值在游戏里能起到很大作用哦~/FCOLOR=191>\
　<--------------------------------------------------------------/FCOLOR=91>\
　　　　　<保卫国家,人人有责!有钱的出钱,有装备的出装备~> \
　<--------------------------------------------------------------/FCOLOR=70>\
　　　　　　　　　　　　　　　　　<ITEMBOX:1:6:513:50:-20:76:76:*:250#请放入系统让你找的装备^250#点击确定按钮提交物品>\
　战场急需物资:{<$STR(T41)>系列装备/FCOLOR=250}一件\
　可获得荣誉值:{<$STR(U41)>点/FCOLOR=254}<荣誉值/FCOLOR=253>\
　<祖玛装备列表|254#以下装备均可用来完成祖玛任务:^250#绿色项链　　骑士手镯　　力量戒指^250#恶魔铃铛　　龙之手镯　　紫碧螺^250#灵魂项链　　三眼手镯　　泰坦戒指^250#裁决之杖　骨玉权杖　龙纹剑　血饮/@沃玛2>　<赤月装备列表|254#以下装备均可用来完成赤月任务:^250#圣战项链　圣战手镯　圣战戒指　圣战头盔^250#天尊项链　天尊手镯　天尊戒指　天尊头盔^250#法神项链　法神手镯　法神戒指　法神头盔^250#怒斩　屠龙　逍遥扇　霸者之刃　龙牙　嗜魂法杖^250#/@沃玛3>　<黄金装备列表|254#以下装备均可用来完成黄金任务:^250#黄金圣战项链　黄金圣战手镯　黄金圣战戒指　黄金圣战头盔^250#黄金天尊项链　黄金天尊手镯　黄金天尊戒指　黄金天尊头盔^250#黄金法神项链　黄金法神手镯　黄金法神戒指　黄金法神头盔^250#黄金天尊道袍　黄金法神披风　黄金天魔神甲　黄金天师长袍^250#黄金霓裳羽衣　黄金圣战宝甲　黄金逍遥扇　黄金嗜魂法杖　黄金屠龙/@黄金1>　 　<$STR(S$提交按钮)>\
　<传奇任务管理|58#传奇管理需要元宝500/@传奇>                          <当前人物荣誉:/FCOLOR=250>{<$GAMEGLORY>/FCOLOR=254}\

#ELSEACT
MESSAGEBOX 您当前没有任务,请先领取任务！！

[@传奇]
#IF
Equal U40 1
#ACT
CloseBigDialogBox
#SAY
小伙子,我最近手头有点紧哦!\
如果你实在找不到我想要的东西,\
你可以给我500元宝,我来帮你完成任务\
但你一定要记住,此事要保密哦!\
\ \
\ \
    <好,成交!/@传奇任务>        <还是算了/@Exit>\
#ELSEACT
MESSAGEBOX 您当前没有任务,请先领取任务！！



[@ItemIntoBox1]
#IF
Equal T41 祖玛
CheckTextList ..\QuestDiary\功能脚本\任务系统\祖玛系列装备.txt <$BOXITEM[1].NAME>
#ACT
Mov S$提交按钮 <确　　定/@提交>
Sendmsg 7 当前放入物品合格.点击确定按钮可提交任务.
GOTO @提交任务1
Break



#IF
Equal T41 赤月
CheckTextList ..\QuestDiary\功能脚本\任务系统\赤月系列装备.txt <$BOXITEM[1].NAME>
#ACT
Mov S$提交按钮 <确　　定/@提交>
Sendmsg 7 当前放入物品合格.点击确定按钮可提交任务.
GOTO @提交任务1
Break



#IF
Equal T41 黄金
CheckTextList ..\QuestDiary\功能脚本\任务系统\黄金系列装备.txt <$BOXITEM[1].NAME>
#ACT
Mov S$提交按钮 <确　　定/@提交>
Sendmsg 7 当前放入物品合格.点击确定按钮可提交任务.
GOTO @提交任务1
#ELSEACT
ReturnBoxItem 1
Mov S$提交按钮 <确　　定>
MESSAGEBOX 你提交的物品不符合任务需求!
Break



[@提交]
#IF
checkitemw 幸运指环 1
#ACT
INC U41 <$STR(U41)>
#IF
checkitemw 真·幸运指环 1
#ACT
INC U41 <$STR(U41)>
#IF
checkitemw 狂·幸运指环 1
#ACT
INC U41 <$STR(U41)>
#IF
NOT Equal <$BOXITEM[1].NAME>
#ACT
DELBOXITEM 1
Mov S$提交按钮 <确　　定>
Sendmsg 0 玩家：「%s」成功提交任务,{荣誉值|251:0:1}增加<$STR(U41)>.(拥有{幸运指环|250:0:1}收益翻倍!)
Sendmsg 0 玩家：「%s」成功提交任务,{荣誉值|251:0:1}增加<$STR(U41)>.(拥有{幸运指环|250:0:1}收益翻倍!)
GuildNoticeMsg 0 250 玩家{「%s」|249:0:1}完成了{[镇关大将]|70:0:1}的任务,{荣誉值|251:0:1}增加了{<$STR(U41)>点|254:0:1}.
GAMEGLORY + <$STR(U41)>
Mov U40 0
Mov U41 0
Mov T41
Close
#ELSEACT
MESSAGEBOX 我要的东西呢!休想蒙混过关
Break



[@ItemOutBox1]
#IF
#ACT
Mov S$提交按钮 <确　　定>
GOTO @提交任务1
Break



[@传奇任务]
#IF
checkitemw 幸运指环 1
#ACT
INC U41 <$STR(U41)>
#IF
checkitemw 真·幸运指环 1
#ACT
INC U41 <$STR(U41)>
#IF
checkitemw 狂·幸运指环 1
#ACT
INC U41 <$STR(U41)>
#IF
checkgamegold > 499
#ACT
gamegold - 500
Sendmsg 0 玩家：「%s」传奇官员成功完成任务,{荣誉值|251:0:1}增加<$STR(U41)>.(拥有{幸运指环|250:0:1}收益翻倍!)
Sendmsg 0 玩家：「%s」传奇官员成功完成任务,{荣誉值|251:0:1}增加<$STR(U41)>.(拥有{幸运指环|250:0:1}收益翻倍!)
GuildNoticeMsg 0 250 玩家{「%s」|249:0:1}传奇了{[镇关大将]|70:0:1},{荣誉值|251:0:1}增加了{<$STR(U41)>点|254:0:1}.
GAMEGLORY + <$STR(U41)>
Mov U40 0
Mov U41 0
Mov T41
Close
#ELSEACT
MESSAGEBOX 你没有500元宝!我可不会帮你完成任务的!
Break